# This is a comment line
# One can can cut and paste this file into gnuplot
# You can do a line at a time or groups of lines up to a plot or splot
#
# Basic plot of the helix
set parametric
splot cos(u),sin(u),u
# by default gnuplot picks a range for the u variable from what
# looks like -5 to 5
# we can change the u range
set urange [0:6*pi]
# see what it is
show urange
# redo the plot (one can do control P's back to an old plot command)
splot cos(u),sin(u),u
# now the helix has 3 complete turns.
#
#
#
# often the number of samples is too small
# the following plot just looks wrong
set urange [0:log(10*pi)]
splot cos(exp(u)),sin(exp(u)),u
show samples
set samples 1000, 1000
show samples
splot cos(exp(u)),sin(exp(u)),u
# the increased sampling (factor of 10 smooths out the curve)
# here are the commands to show the curves of 19-24 section 13.1
splot cos(4*u),u,sin(4*u) #19
splot u,u**2,exp(-u) #20
splot u,1/(1+u**2),u**2 #21
splot exp(-u)*cos(10*u),exp(-u)*sin(10*u),exp(-u) #22
splot cos(u),sin(u),sin(5*u) #23
splot cos(u),sin(u),log(u) #24 -- urange needs to be greater than zero